components/webdata/common/BUILD.gn

# Copyright 2014 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

component("common") {
  output_name = "webdata_common"

  sources = [
    "web_data_request_manager.cc",
    "web_data_request_manager.h",
    "web_data_results.h",
    "web_data_service_base.cc",
    "web_data_service_base.h",
    "web_data_service_consumer.cc",
    "web_data_service_consumer.h",
    "web_database.cc",
    "web_database.h",
    "web_database_backend.cc",
    "web_database_backend.h",
    "web_database_service.cc",
    "web_database_service.h",
    "web_database_table.cc",
    "web_database_table.h",
    "webdata_constants.cc",
    "webdata_constants.h",
    "webdata_export.h",
  ]

  defines = [ "WEBDATA_IMPLEMENTATION" ]

  deps = [
    "//base",
    "//sql",
  ]
}

bundle_data("unit_tests_bundle_data") {
  visibility = [ ":unit_tests" ]
  testonly = true
  sources = [
    "//components/test/data/web_database/version_100.sql",
    "//components/test/data/web_database/version_101.sql",
    "//components/test/data/web_database/version_102.sql",
    "//components/test/data/web_database/version_103.sql",
    "//components/test/data/web_database/version_104.sql",
    "//components/test/data/web_database/version_105.sql",
    "//components/test/data/web_database/version_106.sql",
    "//components/test/data/web_database/version_107.sql",
    "//components/test/data/web_database/version_108.sql",
    "//components/test/data/web_database/version_82.sql",
    "//components/test/data/web_database/version_83.sql",
    "//components/test/data/web_database/version_84.sql",
    "//components/test/data/web_database/version_85.sql",
    "//components/test/data/web_database/version_86.sql",
    "//components/test/data/web_database/version_87.sql",
    "//components/test/data/web_database/version_88.sql",
    "//components/test/data/web_database/version_89.sql",
    "//components/test/data/web_database/version_90.sql",
    "//components/test/data/web_database/version_91.sql",
    "//components/test/data/web_database/version_92.sql",
    "//components/test/data/web_database/version_93.sql",
    "//components/test/data/web_database/version_94.sql",
    "//components/test/data/web_database/version_95.sql",
    "//components/test/data/web_database/version_96.sql",
    "//components/test/data/web_database/version_97.sql",
    "//components/test/data/web_database/version_98.sql",
    "//components/test/data/web_database/version_99.sql",
  ]
  outputs = [ "{{bundle_resources_dir}}/" +
              "{{source_root_relative_dir}}/{{source_file_part}}" ]
}

source_set("unit_tests") {
  testonly = true
  sources = [ "web_database_migration_unittest.cc" ]

  deps = [
    ":common",
    ":unit_tests_bundle_data",
    "//base",
    "//components/autofill/core/browser",
    "//components/autofill/core/common",
    "//components/password_manager/core/browser",
    "//components/search_engines",
    "//components/signin/public/webdata",
    "//sql",
    "//testing/gtest",
  ]
}