components/autofill/android/BUILD.gn

# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/rules.gni")

android_resources("autofill_java_resources") {
  custom_package = "org.chromium.components.autofill"
  resource_dirs = [ "java/res" ]
}

android_library("autofill_java") {
  deps = [
    ":autofill_java_resources",
    "//base:base_java",
    "//content/public/android:content_java",
    "//third_party/android_tools:android_support_v7_appcompat_java",
    "//ui/android:ui_java",
  ]
  java_files = [
    "java/src/org/chromium/components/autofill/AutofillDelegate.java",
    "java/src/org/chromium/components/autofill/AutofillKeyboardAccessory.java",
    "java/src/org/chromium/components/autofill/AutofillPopup.java",
    "java/src/org/chromium/components/autofill/AutofillSuggestion.java",
  ]
}

android_library("provider_java") {
  deps = [
    "//base:base_java",
    "//content/public/android:content_java",
    "//third_party/android_tools:android_support_annotations_java",
  ]
  java_files = [
    "java/src/org/chromium/components/autofill/AutofillProvider.java",
    "java/src/org/chromium/components/autofill/FormData.java",
    "java/src/org/chromium/components/autofill/FormFieldData.java",
  ]
}

generate_jni("jni_headers") {
  sources = [
    "java/src/org/chromium/components/autofill/AutofillProvider.java",
    "java/src/org/chromium/components/autofill/FormData.java",
    "java/src/org/chromium/components/autofill/FormFieldData.java",
  ]
  jni_package = "autofill"
}

static_library("provider") {
  sources = [
    "autofill_provider_android.cc",
    "autofill_provider_android.h",
    "form_data_android.cc",
    "form_data_android.h",
    "form_field_data_android.cc",
    "form_field_data_android.h",
  ]
  deps = [
    ":jni_headers",
    "//components/autofill/core/browser:browser",
    "//content/public/browser",
  ]
}