chrome/browser/media/router/discovery/access_code/BUILD.gn

# Copyright 2021 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//extensions/buildflags/buildflags.gni")
import("//third_party/protobuf/proto_library.gni")

proto_library("discovery_resources_proto") {
  sources = [ "discovery_resources.proto" ]
  cc_generator_options = "lite=true:"
}

static_library("access_code_cast_feature") {
  sources = [
    "access_code_cast_constants.cc",
    "access_code_cast_constants.h",
    "access_code_cast_feature.cc",
    "access_code_cast_feature.h",
  ]
  public_deps = [ "//base" ]
  deps = [
    "//chrome/browser/media/router:media_router_feature",
    "//chrome/browser/profiles:profile",
    "//chrome/common:channel_info",
    "//components/pref_registry:pref_registry",
    "//components/prefs:prefs",
    "//components/user_prefs:user_prefs",
    "//components/version_info:channel",
  ]
}

if (!is_android) {
  static_library("access_code_sink_service") {
    sources = [
      "access_code_cast_discovery_interface.cc",
      "access_code_cast_discovery_interface.h",
      "access_code_cast_pref_updater.cc",
      "access_code_cast_pref_updater.h",
      "access_code_cast_pref_updater_impl.cc",
      "access_code_cast_pref_updater_impl.h",
      "access_code_cast_sink_service.cc",
      "access_code_cast_sink_service.h",
      "access_code_cast_sink_service_factory.cc",
      "access_code_cast_sink_service_factory.h",
      "access_code_media_sink_util.cc",
      "access_code_media_sink_util.h",
    ]
    public_deps = [
      "//base",
      "//chrome/browser/profiles:profile",
      "//components/media_router/browser:browser",
      "//components/media_router/common",
      "//components/media_router/common/mojom:logger",
      "//components/media_router/common/mojom:media_router",
    ]
    deps = [
      ":access_code_cast_feature",
      "//chrome/browser/media/router:router",
      "//chrome/browser/media/router/discovery:discovery",
      "//chrome/browser/media/router/discovery/access_code:discovery_resources_proto",
      "//chrome/browser/profiles:profile",
      "//chrome/browser/signin:identity_manager_provider",
      "//chrome/browser/ui/webui/access_code_cast:mojo_bindings",
      "//components/access_code_cast/common",
      "//components/endpoint_fetcher:endpoint_fetcher",
      "//components/keyed_service/content:content",
      "//components/leveldb_proto:leveldb_proto",
      "//components/media_router/common/providers/cast/channel",
      "//components/pref_registry",
      "//components/prefs:prefs",
      "//components/signin/public/base:base",
      "//components/signin/public/identity_manager:identity_manager",
      "//components/user_manager:user_manager",
      "//content/public/browser",
      "//services/preferences/public/cpp:cpp",
    ]
  }
}