chrome/browser/webauthn/BUILD.gn

# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("webauthn") {
  sources = [
    "shared_types.h",
    "webauthn_metrics_util.h",
    "webauthn_switches.h",
  ]
  public_deps = []

  if (!is_android) {
    sources += [
      "authenticator_request_dialog_model.h",
      "authenticator_transport.h",
      "enclave_manager.h",
      "enclave_manager_factory.h",
      "enclave_manager_interface.h",
      "gpm_enclave_controller.h",
      "gpm_enclave_transaction.h",
      "local_authentication_token.h",
      "passkey_model_factory.h",
    ]
    public_deps += [
      "//base",
      "//build:buildflag_header_h",
      "//chrome/browser/profiles:profile",
      "//chrome/common",
      "//chrome/common:version_header",
      "//components/keyed_service/core",
      "//components/os_crypt/async/common",
      "//components/trusted_vault",
      "//components/webauthn/core/browser:passkey_model",
      "//content/public/browser",
      "//crypto",
      "//device/fido",
      "//google_apis",
    ]
  }
}

if (!is_android) {
  static_library("test_support") {
    testonly = true

    sources = [
      "enclave_authenticator_browsertest_base.cc",
      "enclave_authenticator_browsertest_base.h",
      "fake_magic_arch.cc",
      "fake_magic_arch.h",
      "fake_recovery_key_store.cc",
      "fake_recovery_key_store.h",
      "fake_security_domain_service.cc",
      "fake_security_domain_service.h",
      "test_util.cc",
      "test_util.h",
    ]

    deps = [
      ":webauthn",
      "//base",
      "//chrome/browser",
      "//chrome/browser/sync",
      "//chrome/browser/sync/test/integration:sync_integration_test_support",
      "//chrome/browser/ui",
      "//chrome/test:test_support_ui",
      "//components/os_crypt/sync:test_support",
      "//components/signin/public/identity_manager:test_support",
      "//components/sync:test_support",
      "//components/trusted_vault",
      "//components/trusted_vault:test_support",
      "//components/trusted_vault/proto",
      "//components/webauthn/core/browser",
      "//components/webauthn/core/browser:passkey_model",
      "//crypto:test_support",
      "//device/fido",
      "//device/fido:test_support",
      "//google_apis",
      "//net",
      "//testing/gmock",
      "//testing/gtest",
      "//url",
    ]

    if (is_mac) {
      deps += [ "//device/fido:icloud_keychain_test_support" ]
    }

    data_deps = [ "//third_party/cloud_authenticator/test/local_service:cloud_authenticator_test_service" ]
  }
}