components/compose/core/browser/BUILD.gn

# Copyright 2023 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")

source_set("features") {
  sources = [
    "compose_features.cc",
    "compose_features.h",
  ]

  deps = [ "//base" ]
}

source_set("hats_utils") {
  sources = [ "compose_hats_utils.h" ]

  deps = [ "//base" ]
}

static_library("browser") {
  sources = [
    "compose_client.h",
    "compose_dialog_controller.h",
    "compose_manager.h",
    "compose_manager_impl.cc",
    "compose_manager_impl.h",
    "compose_metrics.cc",
    "compose_metrics.h",
    "compose_utils.cc",
    "compose_utils.h",
    "config.cc",
    "config.h",
  ]

  public_deps = [
    ":features",
    ":hats_utils",
  ]

  deps = [
    ":mojo_bindings",
    "//base",
    "//components/autofill/core/browser",
    "//components/autofill/core/common",
    "//components/keyed_service/core",
    "//components/segmentation_platform/public",
    "//components/strings",
    "//services/metrics/public/cpp:metrics_cpp",
    "//services/metrics/public/cpp:ukm_builders",
  ]
}

mojom("mojo_bindings") {
  sources = [ "compose_enums.mojom" ]
  webui_module_path = "/"
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "compose_manager_impl_unittest.cc",
    "compose_prompt_trimming_unittest.cc",
    "config_unittest.cc",
  ]

  deps = [
    ":browser",
    "//base",
    "//base/test:test_support",
    "//components/autofill/core/browser",
    "//components/autofill/core/browser:test_support",
    "//components/autofill/core/common:test_support",
    "//components/strings",
    "//components/ukm:test_support",
    "//services/metrics/public/cpp:ukm_builders",
    "//testing/gmock",
    "//testing/gtest",
  ]

  # TODO(crbug.com/40031409): Fix code that adds exit-time destructors and
  # enable the diagnostic by removing this line.
  configs += [ "//build/config/compiler:no_exit_time_destructors" ]
}