ios/chrome/browser/widget_kit/model/BUILD.gn

# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/buildflag_header.gni")
import("//build/config/apple/swift_source_set.gni")
import("//build/config/ios/ios_sdk.gni")
import("//ios/build/chrome_build.gni")

buildflag_header("features") {
  _enable_widgets_for_mim =
      ios_enable_widget_kit_extension && ios_enable_widgets_for_mim
  header = "features.h"
  flags = [
    "ENABLE_WIDGET_KIT_EXTENSION=" + "$ios_enable_widget_kit_extension",
    "ENABLE_WIDGETS_FOR_MIM=" + "$_enable_widgets_for_mim",
  ]
}

if (ios_enable_widget_kit_extension) {
  source_set("model") {
    sources = [
      "widget_metrics_util.h",
      "widget_metrics_util.mm",
    ]

    deps = [
      ":model_swift",
      "//base",
      "//ios/chrome/common/app_group",
    ]
    frameworks = [ "Foundation.framework" ]
  }

  swift_source_set("model_swift") {
    sources = [
      "user_defaults_widget_store.swift",
      "widget_metrics_logger.swift",
      "widget_timelines_updater.swift",
    ]

    frameworks = [
      "Foundation.framework",
      "WidgetKit.framework",
    ]
  }

  source_set("unit_tests") {
    testonly = true
    sources = []
    deps = [
      ":model",
      "//base/test:test_support",
      "//ios/web/public/test",
      "//testing/gtest",
    ]
  }
}