content/public/child/BUILD.gn

# Copyright 2014 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ppapi/buildflags/buildflags.gni")

# See //content/BUILD.gn for how this works.
group("child") {
  if (is_component_build) {
    public_deps = [ "//content" ]
  } else {
    public_deps = [ ":child_sources" ]
    if (!is_android) {
      public_deps += [ "//content/gpu" ]
    }
    if (enable_ppapi) {
      public_deps += [ "//content/ppapi_plugin" ]
    }
  }
}

source_set("child_sources") {
  # External code should depend in via ":child" above.
  visibility = [ "//content/*" ]

  sources = [
    "child_thread.h",
    "image_decoder_utils.h",
  ]

  if (is_win) {
    sources += [ "dwrite_font_proxy_init_win.h" ]
  }

  configs += [
    "//build/config/compiler:wexit_time_destructors",
    "//content:content_implementation",
  ]

  deps = [
    "//content/child",  # Must not be public_deps!
    "//content/public/common:common_sources",
    "//gin",
  ]

  allow_circular_includes_from = [
    # This target is a pair with content/child. They always go together and
    # include headers from each other.
    "//content/child",
  ]
}