third_party/libjingle/BUILD.gn

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/features.gni")

config("jingle_unexported_configs") {
  include_dirs = [
    "../../third_party/webrtc_overrides",
    "../../testing/gtest/include",
    "../../third_party",
    "../../third_party/libyuv/include",
    "../../third_party/usrsctp/usrsctplib",
  ]
}

config("jingle_public_configs") {
  include_dirs = [
    "../../third_party/webrtc_overrides",
    "../../testing/gtest/include",
    "../../third_party",
  ]
}

group("jingle_deps") {
  public_deps = [
    "//third_party/expat",
  ]
  deps = [
    "//base",
    "//crypto:platform",
    "//net",
  ]
}

static_library("libjingle") {
  # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]

  public_deps = [
    ":jingle_deps",

    # TODO(kjellander): Start cleaning up this target as soon as
    # https://codereview.chromium.org/2022833002/ is landed. The target should
    # be removed entirely if possible.
    "//third_party/webrtc/base:rtc_base",
  ]
  deps = [
    "//third_party/webrtc/p2p:rtc_p2p",
  ]

  # From libjingle_common.gypi's conditions list.
  if (is_win) {
    cflags = [ "/wd4005" ]
  }

  if (is_nacl) {
    # For NACL, we have to add a default implementation for field_trail.
    deps += [
      "//native_client_sdk/src/libraries/nacl_io",
      "//third_party/webrtc/system_wrappers:field_trial_default",
    ]
  } else {
    # Otherwise, we just add the field_trial which redirects to base.
    sources = [
      "../webrtc_overrides/field_trial.cc",
    ]
  }

  configs += [
    ":jingle_unexported_configs",
    "//third_party/webrtc:common_config",
  ]
  public_configs = [
    ":jingle_public_configs",
    "//third_party/webrtc:common_inherited_config",
  ]
}