components/grpc_support/BUILD.gn

source_set("headers") {
  public = [ "include/bidirectional_stream_c.h" ]
}

source_set("grpc_support") {
  sources = [
    "bidirectional_stream.cc",
    "bidirectional_stream.h",
    "bidirectional_stream_c.cc",
    "include/bidirectional_stream_c.h",
  ]

  deps = [
    ":headers",
    "//base",
    "//net",
    "//url",
  ]
}

# Depends on ":grpc_support" implementation.
source_set("bidirectional_stream_unittest") {
  testonly = true
  sources = [ "bidirectional_stream_unittest.cc" ]

  deps = [
    ":grpc_support",
    "//base",
    "//net",
    "//net:test_support",
  ]

  public_deps = [ "//components/grpc_support/test:get_stream_engine_header" ]
}

# Depends on ":headers" to avoid ":grpc_support" implementation.
source_set("bidirectional_stream_test") {
  testonly = true
  sources = [ "bidirectional_stream_unittest.cc" ]

  deps = [
    ":headers",
    "//base",
    "//net",
    "//net:test_support",
  ]

  public_deps = [ "//components/grpc_support/test:get_stream_engine_header" ]
}