components/page_info/BUILD.gn

if (is_android) {
  import("//build/config/android/rules.gni")
}

static_library("page_info") {
  sources = [
    "features.cc",
    "features.h",
    "page_info.cc",
    "page_info.h",
    "page_info_delegate.h",
    "page_info_ui.cc",
    "page_info_ui.h",
    "page_info_ui_delegate.h",
  ]

  deps = [
    "//base",
    "//build:chromeos_buildflags",
    "//components/browsing_data/content",
    "//components/content_settings/browser",
    "//components/content_settings/core/browser",
    "//components/password_manager/core/browser",
    "//components/permissions",
    "//components/prefs",
    "//components/safe_browsing:buildflags",
    "//components/safe_browsing/content/password_protection",
    "//components/safe_browsing/core:csd_proto",
    "//components/safe_browsing/core/password_protection:password_protection_metrics_util",
    "//components/security_interstitials/content:security_interstitial_page",
    "//components/security_interstitials/core",
    "//components/security_state/core",
    "//components/signin/public/identity_manager",
    "//components/ssl_errors:ssl_errors",
    "//components/strings:components_chromium_strings_grit",
    "//components/strings:components_strings_grit",
    "//components/subresource_filter/core/browser",
    "//components/ukm/content",
    "//components/url_formatter",
    "//components/vector_icons:vector_icons",
    "//content/public/browser:browser",
    "//services/device/public/cpp:device_features",
    "//services/metrics/public/cpp:ukm_builders",
  ]

  if (is_android) {
    deps += [
      "//components/browser_ui/util/android",
      "//components/password_manager/core/browser:password_manager_java_enums_srcjar",
      "//components/resources:android_resources",
    ]
  } else {
    deps += [ "//ui/native_theme" ]
  }
}

if (is_android) {
  java_cpp_enum("page_info_action_javagen") {
    sources = [ "page_info.h" ]
  }
}