chrome/browser/webapps/android/BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/config.gni")
import("//build/config/android/rules.gni")

source_set("android") {
  sources = [
    "features.cc",
    "features.h",
    "pwa_bottom_sheet_controller.cc",
    "pwa_bottom_sheet_controller.h",
  ]

  deps = [
    "//base",
    "//chrome/browser/webapps/android:jni_headers",
    "//components/url_formatter:url_formatter",
    "//components/webapps/browser",
    "//content/public/browser:browser",
    "//services/device/public/mojom",
    "//skia",
    "//third_party/blink/public/common:common",
  ]
}

android_library("java") {
  resources_package = "org.chromium.chrome.browser.webapps"

  sources = [
    "java/src/org/chromium/chrome/browser/webapps/AddToHomescreenBottomSheetViewBinder.java",
    "java/src/org/chromium/chrome/browser/webapps/AddToHomescreenIPHController.java",
    "java/src/org/chromium/chrome/browser/webapps/ImageZoomView.java",
    "java/src/org/chromium/chrome/browser/webapps/PwaBottomSheetController.java",
    "java/src/org/chromium/chrome/browser/webapps/PwaBottomSheetControllerFactory.java",
    "java/src/org/chromium/chrome/browser/webapps/PwaBottomSheetControllerProvider.java",
    "java/src/org/chromium/chrome/browser/webapps/PwaInstallBottomSheetContent.java",
    "java/src/org/chromium/chrome/browser/webapps/PwaInstallBottomSheetView.java",
  ]

  deps = [
    ":java_resources",
    ":jni_headers",
    "//base:base_java",
    "//chrome/browser/feature_engagement:java",
    "//chrome/browser/flags:java",
    "//chrome/browser/profiles/android:java",
    "//chrome/browser/tab:java",
    "//chrome/browser/ui/android/appmenu:java",
    "//chrome/browser/ui/android/strings:ui_strings_grd",
    "//chrome/browser/user_education:java",
    "//components/browser_ui/bottomsheet/android:java",
    "//components/browser_ui/styles/android:java_resources",
    "//components/embedder_support/android:util_java",
    "//components/feature_engagement:feature_engagement_java",
    "//components/messages/android:java",
    "//components/webapk/android/libs/client:java",
    "//components/webapps/browser/android:java",
    "//content/public/android:content_java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_recyclerview_recyclerview_java",
    "//third_party/androidx:androidx_vectordrawable_vectordrawable_java",
    "//ui/android:ui_no_recycler_view_java",
    "//url:gurl_java",
  ]

  annotation_processor_deps = [ "//base/android/jni_generator:jni_processor" ]
}

generate_jni("jni_headers") {
  sources = [
    "java/src/org/chromium/chrome/browser/webapps/PwaBottomSheetController.java",
    "java/src/org/chromium/chrome/browser/webapps/PwaBottomSheetControllerProvider.java",
  ]
}

android_resources("java_resources") {
  sources = [
    "java/res/layout/image_zoom_view.xml",
    "java/res/layout/pwa_install_bottom_sheet_content.xml",
    "java/res/layout/pwa_install_bottom_sheet_toolbar.xml",
    "java/res/values/dimens.xml",
  ]
  deps = [
    "//chrome/browser/ui/android/strings:ui_strings_grd",
    "//components/webapk/android/libs/common:splash_resources",
  ]
}