extensions/browser/api/socket/BUILD.gn

# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chromeos/ui_mode.gni")
import("//extensions/buildflags/buildflags.gni")

assert(enable_extensions,
       "Cannot depend on extensions because enable_extensions=false.")

source_set("socket") {
  sources = [
    "mojo_data_pump.cc",
    "mojo_data_pump.h",
    "socket.cc",
    "socket.h",
    "socket_api.cc",
    "socket_api.h",
    "tcp_socket.cc",
    "tcp_socket.h",
    "tls_socket.cc",
    "tls_socket.h",
    "udp_socket.cc",
    "udp_socket.h",
  ]

  configs += [
    # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
    "//build/config/compiler:no_size_t_to_int_warning",
  ]

  deps = [
    "//build:chromeos_buildflags",
    "//content/public/browser",
    "//content/public/common",
    "//extensions/browser/api",
    "//extensions/common",
    "//extensions/common/api",
  ]

  if (is_chromeos_ash) {
    sources += [
      "app_firewall_hole_manager.cc",
      "app_firewall_hole_manager.h",
    ]

    deps += [
      "//chromeos/network",
      "//components/keyed_service/content",
    ]
  }

  public_deps = [ "//extensions/browser:browser_sources" ]
}