chrome/browser/contextual_tasks/BUILD.gn

# Copyright 2025 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")

source_set("contextual_tasks") {
  sources = [
    "contextual_tasks_context_controller_factory.cc",
    "contextual_tasks_context_controller_factory.h",
    "contextual_tasks_service_factory.cc",
    "contextual_tasks_service_factory.h",
  ]

  deps = [
    ":internal",
    "//base",
    "//chrome/browser/autocomplete:aim_eligibility_service",
    "//chrome/browser/favicon",
    "//chrome/browser/history",
    "//chrome/browser/sync",
    "//chrome/common:channel_info",
    "//components/contextual_tasks/internal",
    "//components/contextual_tasks/public",
    "//components/favicon/core",
    "//components/history/core/browser",
    "//components/omnibox/browser",
    "//components/sync/model",
    "//content/public/browser",
  ]

  public_deps = [
    ":public",
    "//chrome/browser/profiles:profile",
  ]
}

source_set("public") {
  sources = [
    "contextual_tasks_context_controller.cc",
    "contextual_tasks_context_controller.h",
  ]

  public_deps = [
    "//base",
    "//components/contextual_tasks/public",
    "//components/keyed_service/core",
    "//components/sessions:session_id",
  ]
}

source_set("internal") {
  visibility = [ ":*" ]

  sources = [
    "contextual_tasks_context_controller_impl.cc",
    "contextual_tasks_context_controller_impl.h",
  ]

  deps = [
    ":public",
    "//components/contextual_tasks/public",
    "//components/keyed_service/core",
    "//components/omnibox/browser",
    "//components/sessions:session_id",
  ]
}

if (!is_android) {
  source_set("ui") {
    sources = [
      "contextual_tasks_page_handler.cc",
      "contextual_tasks_page_handler.h",
      "contextual_tasks_side_panel_coordinator.cc",
      "contextual_tasks_side_panel_coordinator.h",
      "contextual_tasks_ui.cc",
      "contextual_tasks_ui.h",
      "contextual_tasks_ui_service.cc",
      "contextual_tasks_ui_service.h",
      "contextual_tasks_ui_service_factory.cc",
      "contextual_tasks_ui_service_factory.h",
    ]

    public_deps = [
      ":contextual_tasks",
      ":mojo_bindings",
      "//components/contextual_tasks/public:feature_list",
      "//content/public/browser",
      "//content/public/common",
      "//ui/webui",
      "//url",
    ]

    deps = [
      "//base",
      "//chrome/browser/profiles:profile",
      "//chrome/browser/resources/contextual_tasks:resources",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/ui/views/side_panel",
      "//chrome/browser/ui/webui",
      "//chrome/browser/ui/webui/top_chrome",
      "//components/contextual_tasks/public:feature_list",
      "//components/keyed_service/core",
    ]
  }

  mojom("mojo_bindings") {
    sources = [ "contextual_tasks.mojom" ]
    webui_module_path = "/"
    public_deps = [
      "//mojo/public/mojom/base",
      "//url/mojom:url_mojom_gurl",
    ]
  }
}

source_set("unit_tests") {
  testonly = true

  sources = [
    "contextual_tasks_context_controller_factory_unittest.cc",
    "contextual_tasks_context_controller_impl_unittest.cc",
    "contextual_tasks_service_factory_unittest.cc",
  ]

  deps = [
    ":contextual_tasks",
    ":internal",
    ":public",
    "//base",
    "//base/test:test_support",
    "//chrome/test:test_support",
    "//components/contextual_tasks/public",
    "//content/test:test_support",
    "//services/network/public/cpp",
    "//testing/gmock",
    "//testing/gtest",
  ]
}