components/url_matcher/BUILD.gn

# Copyright 2014 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//testing/libfuzzer/fuzzer_test.gni")

component("url_matcher") {
  sources = [
    "regex_set_matcher.cc",
    "regex_set_matcher.h",
    "url_matcher.cc",
    "url_matcher.h",
    "url_matcher_constants.cc",
    "url_matcher_constants.h",
    "url_matcher_export.h",
    "url_matcher_factory.cc",
    "url_matcher_factory.h",
    "url_util.cc",
    "url_util.h",
  ]

  defines = [ "URL_MATCHER_IMPLEMENTATION" ]

  public_deps = [
    "//base",
    "//components/google/core/common",
    "//components/url_formatter",
    "//net",
    "//third_party/re2",
    "//url",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "regex_set_matcher_unittest.cc",
    "url_matcher_factory_unittest.cc",
    "url_matcher_unittest.cc",
    "url_util_unittest.cc",
  ]
  deps = [
    ":url_matcher",
    "//base/test/:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//url",
  ]
}

fuzzer_test("url_matcher_fuzzer") {
  sources = [ "url_matcher_fuzzer.cc" ]
  deps = [
    ":url_matcher",
    "//base",
    "//base:i18n",
  ]
}