content/browser/attribution_reporting/BUILD.gn

# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")
import("//third_party/protobuf/proto_library.gni")

proto_library("attribution_reporting_proto") {
  sources = [ "attribution_reporting.proto" ]
  generate_python = false
}

mojom("mojo_bindings") {
  sources = [ "attribution_reporting.mojom" ]
  webui_module_path = "/"
  use_typescript_sources = true
}

mojom("store_source_result_mojom") {
  sources = [ "store_source_result.mojom" ]
  webui_module_path = "/"
  use_typescript_sources = true
}

mojom("internals_mojo_bindings") {
  sources = [ "attribution_internals.mojom" ]
  public_deps = [
    ":mojo_bindings",
    ":store_source_result_mojom",
    "//components/attribution_reporting:mojom",
    "//components/attribution_reporting:registration_mojom",
    "//components/attribution_reporting:source_type_mojom",
    "//services/network/public/mojom:mojom_attribution",
    "//services/network/public/mojom:mojom_schemeful_site",
    "//url/mojom:url_mojom_origin",
  ]
  webui_module_path = "/"
  use_typescript_sources = true

  cpp_typemaps = [
    {
      types = [
        {
          mojom = "attribution_internals.mojom.AggregatableAttributionReportID"
          cpp = "::content::AttributionReport::AggregatableAttributionData::Id"
        },
        {
          mojom = "attribution_internals.mojom.EventLevelReportID"
          cpp = "::content::AttributionReport::EventLevelData::Id"
        },
        {
          mojom = "attribution_internals.mojom.ReportID"
          cpp = "::content::AttributionReport::Id"
        },
      ]
      traits_headers = [
        "attribution_internals_mojom_traits.h",
        "attribution_report.h",
      ]
      traits_sources = [ "attribution_internals_mojom_traits.cc" ]
      traits_deps = [
        ":attribution_reporting_proto",

        # //content/common/aggregatable_report.mojom is transitively included.
        "//content/common:mojo_bindings",

        # //components/aggregation_service/aggregation_service.mojom is transitively included.
        "//components/aggregation_service:mojom",
      ]
    },
  ]
}

# Platforms where sqlite_dev_shell is defined.
if (is_win || is_mac || is_linux || is_chromeos) {
  source_set("sqlite_test_utils") {
    testonly = true
    sources = [
      "sql_query_plan_test_util.cc",
      "sql_query_plan_test_util.h",
    ]

    deps = [
      "//base",
      "//testing/gmock",
    ]

    data_deps = [ "//third_party/sqlite:sqlite_dev_shell" ]
  }
}