chrome/browser/profiles/BUILD.gn

# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chromeos/ui_mode.gni")
import("//extensions/buildflags/buildflags.gni")

# This target should be the default place for adding public interface things
# (ie, non-factory, non-impl). There will likely need to be a :factory or :impl
# target (maybe both) for those eventually.
source_set("profiles") {
  sources = [
    "incognito_helpers.cc",
    "incognito_helpers.h",
    "profile_key.cc",
    "profile_key.h",
  ]

  if (is_android) {
    sources += [
      "profile_android.cc",
      "profile_android.h",
      "profile_key_android.cc",
      "profile_key_android.h",
    ]
  }

  # Cannot depend on //chrome/browser:browser.
  deps = []
  if (is_android) {
    deps += [
      "//chrome/browser/profiles/android:jni_headers",
      "//content/public/browser",
    ]
  }

  public_deps = [
    ":profile",
    "//components/leveldb_proto",
  ]
}

# This target should be very minimal, likely no new sources should be added
# here. It should not depend on anything besides flags/constants in
# //chrome/browser/* because almost everything else depends on it.
source_set("profile") {
  sources = [
    "profile.cc",
    "profile.h",
    "profile_keyed_service_factory.cc",
    "profile_keyed_service_factory.h",
    "profile_observer.h",
    "profile_selections.cc",
    "profile_selections.h",
    "refcounted_profile_keyed_service_factory.cc",
    "refcounted_profile_keyed_service_factory.h",
  ]

  public_deps = [ "//base" ]

  # Cannot depend on //chrome/browser:browser.
  deps = [
    "//build:chromeos_buildflags",
    "//chrome/browser/browsing_data:constants",
    "//chrome/common:buildflags",
    "//chrome/common:constants",
    "//components/keyed_service/content",
    "//components/language/core/browser",
    "//components/live_caption:constants",
    "//components/media_router/common",
    "//components/pref_registry",
    "//components/prefs",
    "//components/profile_metrics",
    "//components/search_engines",
    "//components/sync/service",
    "//components/variations",
    "//content/public/browser",
    "//extensions/buildflags",
  ]
  if (enable_extensions) {
    deps += [ "//extensions/browser" ]
  }
  if (is_chromeos) {
    deps += [ "//chromeos/constants" ]
  }
  if (is_chromeos_ash) {
    deps += [
      "//ash/constants",
      "//chromeos/ash/components/browser_context_helper",
    ]
  }
  if (is_chromeos_lacros) {
    deps += [
      "//chromeos/lacros",
      "//chromeos/startup",
    ]
  }
  if (is_android) {
    deps += [ "//chrome/browser/profiles/android:jni_headers" ]
  }
}