chrome/browser/ui/webui/BUILD.gn

# Copyright 2022 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chromeos/ui_mode.gni")

source_set("configs") {
  sources = [
    "chrome_untrusted_web_ui_configs.cc",
    "chrome_untrusted_web_ui_configs.h",
    "chrome_web_ui_configs.cc",
    "chrome_web_ui_configs.h",
  ]

  configs += [ "//build/config/compiler:wexit_time_destructors" ]

  deps = [
    "//chrome/browser/ui:ui",
    "//components/compose:buildflags",
    "//components/lens:buildflags",
    "//content/public/browser",
    "//extensions/buildflags:buildflags",
    "//printing/buildflags",
    "//skia",
    "//third_party/abseil-cpp:absl",
  ]

  # Includes Ash Chrome and Lacros Chrome
  if (is_chromeos) {
    deps += [ "//chromeos/constants" ]
  }

  if (is_chromeos_ash) {
    sources += [
      "ash/chrome_untrusted_web_ui_configs_chromeos.cc",
      "ash/chrome_untrusted_web_ui_configs_chromeos.h",
      "ash/chrome_web_ui_configs_chromeos.cc",
      "ash/chrome_web_ui_configs_chromeos.h",
    ]

    deps += [
      "//ash/constants",
      "//ash/webui/color_internals",
      "//ash/webui/demo_mode_app_ui",
      "//ash/webui/diagnostics_ui",
      "//ash/webui/eche_app_ui",
      "//ash/webui/file_manager:file_manager_untrusted_ui",
      "//ash/webui/firmware_update_ui",
      "//ash/webui/help_app_ui",
      "//ash/webui/os_feedback_ui",
      "//ash/webui/print_management",
      "//ash/webui/print_preview_cros",
      "//ash/webui/scanning",
      "//ash/webui/shimless_rma",
      "//ash/webui/shortcut_customization_ui",
      "//ash/webui/status_area_internals",
      "//ash/webui/vc_background_ui",
      "//chrome/browser/ash",
      "//components/cross_device/logging",
    ]

    if (!is_official_build) {
      deps += [ "//ash/webui/sample_system_web_app_ui" ]
    }
  }
}