showcase/credential_provider/BUILD.gn

# Copyright 2020 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ios/build/chrome_build.gni")

source_set("credential_provider") {
  sources = []
  deps = [ "//ios/showcase/common" ]
  if (ios_enable_credential_provider_extension) {
    sources += [
      "sc_credential_list_coordinator.h",
      "sc_credential_list_coordinator.mm",
    ]
    deps += [
      "//ios/chrome/common/credential_provider:ui",
      "//ios/chrome/credential_provider_extension/ui",
    ]
  }
  frameworks = [ "UIKit.framework" ]
  configs += [ "//build/config/compiler:enable_arc" ]
}

source_set("eg2_tests") {
  defines = [ "CHROME_EARL_GREY_2" ]
  configs += [
    "//build/config/compiler:enable_arc",
    "//build/config/ios:xctest_config",
  ]
  testonly = true
  sources = []
  deps = [
    "//base",
    "//ios/chrome/common/ui/confirmation_alert",
    "//ios/showcase/test:eg2_test",
    "//ios/testing/earl_grey:eg_test_support+eg2",
    "//ios/third_party/earl_grey2:test_lib",
    "//ui/base",
  ]

  if (ios_enable_credential_provider_extension) {
    sources += [ "credential_provider_egtest.mm" ]
  }

  frameworks = [ "UIKit.framework" ]
}